Sari la conținut

Poză

Generator semnal xr 2206

- - - - -

  • Conecteaza-te daca doresti sa raspunzi
31 răspunsuri în acest subiect

#31
gsabac

gsabac

    Senior Member

  • Tehnium Azi
  • 1.846 postari
  • Resedinta:Bucuresti

A realizat un generator functional decadic virtual pina la 1MHz cu XR2206. Pentru aceata am descarcat libraria XR2206.lib

 din arhiva Wiky, am comparat schema circuitului din PDF cu continutul librariei si am sters componentele aditionale

 care nu fac parte din circuit, un condensator de 10n pus pentru frecventa si 2 rezistente de 30K pentru Freq1 si Freq2.

**********************************************************************************************************

* XR2206.asc V0.9 este un circuit functional cu component aditionale
* schema modificata pentru XR2206 componenta
.subckt XR2206 AM STO MO VCC TC1 TC2 TR1 TR2 FSK BIAS SYNCO COM WV1 WV2 SYM1 SYM2
Q1 N033 N023 N040 0 NPN1
Q2 TC2 N023 TR1 0 NPN1
Q3 TC1 N022 TR1 0 NPN1
Q4 N034 N022 N040 0 NPN1
Q5 N014 N033 TC2 0 NPN1
Q6 N015 N034 TC1 0 NPN1
Q7 N014 N009 vo 0 PNP1
Q8 N022 N014 N009 0 PNP1
Q9 N015 N009 vo 0 PNP1
D1 vo N009 DD1
Q10 N023 N015 N009 0 PNP1
D2 N015 N014 DD1
D3 N014 N015 DD1
D4 N023 BIAS DD1
D5 N022 BIAS DD1
*R1 TR1 COM 20k    ;bebe, componenta externa
R2 N025 N033 4k
R3 N025 N034 4k
D6 N018 N025 DD1
D7 vo N018 DD1
V2 N013 vo 0
C1 TC2 TC1 10p   ; bebe  A fost 10n
R4 N022 BIAS 1e6
R5 N023 BIAS 1e6
Q11 N010 N023 N029 0 NPN1
D8 VCC N010 DD1
Q12 N010 N022 N030 0 NPN1
Q13 N039 N035 N029 0 PNP1
Q14 N037 N035 N030 0 PNP1
D9 N039 COM DD1
Q15 N037 N039 COM 0 NPN1
Q16 SYNCO N037 COM 0 NPN1
Q17 N035 N010 VCC 0 PNP1
Q18 WV2 N047 SYM1 0 NPN1
Q19 WV1 N047 SYM2 0 NPN1
Q20 VCC N016 WV2 0 NPN1
Q21 VCC N017 WV1 0 NPN1
R7 SYM1 COM 2.2k
R8 SYM2 COM 2.2k
Q22 N027 WV1 N041 0 NPN1
Q23 N026 WV2 N042 0 NPN1
R9 N041 N053 500
R10 N042 N053 500
Q24 N031 AM N043 0 NPN1
Q26 N002 N026 N031 0 NPN1
Q27 N003 N027 N031 0 NPN1
R12 N043 N052 1.3k
Q28 N032 N038 N044 0 NPN1
Q30 N002 N027 N032 0 NPN1
Q31 N003 N026 N032 0 NPN1
R14 N044 N052 1.3k
D14 VCC N011 DD1
D15 N011 N020 DD1
R13 AM N052 1G
R15 VCC N038 5k
R16 N038 COM 5k
Q25 N020 N020 N027 0 NPN1
Q29 N020 N020 N026 0 NPN1
Q34 N048 N021 N019 0 PNP1
Q35 N048 N048 COM 0 NPN1
Q36 N045 N048 COM 0 NPN1
Q37 MO MO N045 0 NPN1
Q38 N024 N024 MO 0 NPN1
Q39 N024 N021 N008 0 PNP1
Q40 VCC N024 N028 0 NPN1 5
R17 N028 N036 50
R18 STO N036 450
Q41 COM N045 N036 0 PNP1 5
Q42 N066 FSK COM 0 NPN1
Q43 N064 N066 N068 0 NPN1
R22 FSK COM 1g
R23 N056 N066 10k
D10 N071 COM DD1
D11 N068 N071 DD1
D12 N057 N064 DD1
R24 N056 N057 5k
Q44 N056 N057 TR1 0 NPN1
R25 TR1 COM 1g
D17 N058 N065 DD1
R27 N056 N058 5k
Q48 N056 N058 TR2 0 NPN1
R28 TR2 COM 1g
D18 N070 N072 DD1
D13 N072 COM DD1
Q47 COM N066 N067 0 PNP1
Q49 N065 N062 N070 0 NPN1
R29 N056 N067 10k
Q46 TC1 N022 TR2 0 NPN1
Q45 TC2 N023 TR2 0 NPN1
*R26 TR2 COM 20k               ;bebe, component externa
Q50 N062 N067 N069 0 NPN1
D16 N069 COM DD1
R31 N056 N062 10k
R32 N056 N069 50k
R33 N056 N070 50k
Q51 COM N063 BIAS 0 PNP1
Q52 N056 N061 N063 0 NPN1
R30 N063 COM 5k
B1 N060 COM V=limit(0,0.32*V(VCC,COM),3.07)
R38 N060 N061 100
C3 N061 COM 100p
B2 N013 COM V=limit(0,0.7*V(VCC,COM),6.9)
F1 VCC COM V2 1
B3 N046 COM V=limit(0, 0.25*(V(VCC,COM)-5),1.75)
R39 N046 N047 100
C4 N047 COM 100p
V1 N059 N056 0
F2 VCC COM V1 1
B4 N059 COM V=limit(0,0.41*V(VCC,COM),5)
Q53 N040 N050 COM 0 NPN1
R40 vo BIAS 50k
R41 N053 COM 1e7
Q55 N055 N055 COM 0 NPN1
Q56 N053 N055 COM 0 NPN1
B6 COM N055 I=limit(0,(V(VCC,COM)-5)*0.8m,1.5m)
Q57 N054 N054 COM 0 NPN1
Q58 N052 N054 COM 0 NPN1
B5 COM N054 I=limit(0,(V(VCC,COM)-5)*1m,3.5m)
Q59 N051 N051 COM 0 NPN1
Q60 N035 N051 COM 0 NPN1
B7 COM N051 I=limit(0,(V(VCC,COM)-5)*0.05m,.16m)
Q61 N050 N050 COM 0 NPN1
B8 COM N050 I=limit(0,(V(VCC,COM)-5)*0.05m,.189m)
Q54 N019 N003 VCC 0 PNP1
Q62 N008 N002 VCC 0 PNP1
Q32 N002 N002 VCC 0 PNP1 4.5
Q33 N003 N003 VCC 0 PNP1 4.5
D19 VCC N004 DD1
D20 N007 N012 DD1
D21 N004 N007 DD1
R42 N021 COM 15k
I1 N012 N021 -3m
R43 N012 N021 100
Q63 N001 N001 VCC 0 PNP1
Q64 N008 N001 VCC 0 PNP1
Q65 N049 N049 COM 0 NPN1
Q66 N045 N049 COM 0 NPN1
B9 N001 N049 I=limit(0,(V(VCC,COM)-5)*0.15m,0.5m)
R45 WV2 WV1 100k
I2 N005 COM 1m load
I3 N006 COM 1m load
R11 WV2 WV1 180g
Q67 VCC TC1 N005 0 NPN1
Q68 VCC TC2 N006 0 NPN1
R47 N005 N016 500
R48 N006 N017 500
R49 N016 N017 400
.model DD1 D(Is=1e-15 Rs=10 Cjo=1p)
.model NPN1 NPN(Is=1e-15 BF=100 Cje=2p Cjc=1p Rb=20 Re=2)
.model PNP1 PNP(Is=1e-15 BF=25 Cje=2p Cjc=1p Rb=20 Re=2)
.ends xr2206

**********************************************************************************************************

Apoi am construit modelul grafic pentru simulare XR2206.asy exact ca in catalogul EXAR.

 Schema este urmatoarea; Click pentru marire.

    Fișier atașat  generator cu XR2206.jpg   223,3K   0 descărcări

 Prin tatonarea valorilor wiper se realizeaza reglajul din trimeri, pentru o functionare corecta.

Cu valorile din schema, reglajul este linear intre 100KHz si 1MHz, adica in raport de 10:1.

Bineinteles gamele se pot realiza prin introducerea unui comutator cu diverse valori C2.

A rezultat nivel reglabil si comutat decadic, reglaj de frecventa linear, semnal dreptunghiular

  in 50 Ohmi cu fronturi de 50nS si distorsiuni minime de 0,8%

 

@gsabac


Editat de gsabac, 14 iulie 2018 - 08:07 .

  • Nardu ii(le) place mesajul asta

#32
gsabac

gsabac

    Senior Member

  • Tehnium Azi
  • 1.846 postari
  • Resedinta:Bucuresti

Performantele obtinute sunt in grafice. Click pentru marire

  Fișier atașat  XR2206 ~1000Hz FFT si distorsiuni.jpg   384,88K   0 descărcări

Pentru calculul distorsiunilor, cind se cunoaste amplitudinea semnalului si armonicelor, se poate folosi formula:

 Fișier atașat  formula de calcul a distorsiunilor.jpg   26,17K   0 descărcări

Semnalul dreptunghiular de iesire, este defazat cu 90 de grade fata de sinusoida de la iesire, ca in poza.

  Fișier atașat  semnal sinusoidal si dreptunghiular.jpg   158,11K   0 descărcări

 

@gsabac


Editat de gsabac, Ieri, 09:39 .

  • Nardu ii(le) place mesajul asta




0 utilizatori citesc acest topic

0 utilizatori, 0 vizitatori, 0 utilizatori anonimi

emil.matei.ro Cel mai cuprinzator director romanesc